home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 073 - ProSEL 3.3.dsk / PRINT.NAMES.bas < prev    next >
BASIC Source File  |  2019-02-17  |  2KB  |  48 lines
  1. 1  REM ************************
  2. 2  REM *                      *
  3. 3  REM * Program to print the *
  4. 4  REM * application list in  *
  5. 5  REM * /HARD1/PROSEL.       *
  6. 6  REM *                      *
  7. 7  REM ************************
  8. 8  REM 
  9. 10  PRINT  CHR$(12): HOME : PRINT : LOMEM: 4 *4096
  10. 20  ONERR  GOTO 620
  11. 30  PRINT  CHR$(4)"BLOAD /HARD1/PROSEL,A$2000"
  12. 40  POKE 216,0
  13. 50  PRINT "This program prints the selection"
  14. 60  PRINT "list in PROSEL.  Do you want hard"
  15. 70  PRINT "copy? (Y/N) ";
  16. 80  GET A$: IF  ASC(A$) > ASC("Z")  THEN A$ =  CHR$( ASC(A$) -32)
  17. 90  IF A$ = "N"  THEN 120
  18. 100  IF A$ < >"Y"  THEN 80
  19. 110 PR = 1: PRINT  CHR$(21): PRINT  CHR$(4)"PR#1"
  20. 120  PRINT :LOC = 2 *4096:LOC = LOC + PEEK(LOC +3) +256 * PEEK(LOC +4)
  21. 130  IF   NOT  PEEK(LOC)  THEN 600
  22. 140 S$ = ""
  23. 150 L =  PEEK(LOC): IF L >159  THEN S$ = S$ + CHR$(L -128)
  24. 160  IF L >128  THEN LOC = LOC +1: GOTO 150
  25. 170  IF   NOT L  THEN 600
  26. 180 P$ = "": FOR I = LOC +1 TO LOC +L
  27. 190 P$ = P$ + CHR$( PEEK(I)): NEXT I
  28. 200 LOC = I
  29. 210 L =  PEEK(LOC): IF   NOT L  THEN 600
  30. 220 A$ = "": FOR I = LOC +1 TO LOC +L
  31. 230 A$ = A$ + CHR$( PEEK(I)): NEXT I
  32. 240 LOC = I
  33. 250 U$ = "<none>":L =  PEEK(LOC): IF L = 0  OR L >127  THEN 500
  34. 260 U$ = "": FOR I = LOC +1 TO LOC +L
  35. 270 U$ = U$ + CHR$( PEEK(I)): NEXT I
  36. 280 LOC = I
  37. 500  PRINT : PRINT "Application: ";S$
  38. 510  PRINT "Prefix:      ";P$
  39. 520  PRINT "Pathname:    ";A$
  40. 530  PRINT "Startup:     ";U$
  41. 540  GOTO 130
  42. 600  IF PR  THEN  PRINT  CHR$(4)"PR#0"
  43. 610  END 
  44. 620  POKE 216,0
  45. 630  PRINT  CHR$(4)"CLOSE"
  46. 640  PRINT "Error: /HARD1/PROSEL not found."
  47. 650  PRINT "This program must be changed if you"
  48. 660  PRINT "have used another pathname for it."